MT#5299 API: GET and POST billing profiles.

Build.PL

@@ -61,6 +61,7 @@ my $builder = Local::Module::Build->new(
         'IO::Compress::Xz' => 0,
         'IPC::System::Simple' => 0,
         'JSON::Pointer' => 0,
+        'JSON::Types' => 0,
         'JSON::Tiny::Subclassable' => 0,
         'Log::Log4perl::Catalyst' => 0,
         'Module::Runtime' => 0,

debian/control

@@ -25,6 +25,7 @@ Build-Depends: debhelper (>= 8),
                libhtml-formhandler-perl (>= 0.40026),
                libhtml-parser-perl,
                libio-compress-lzma-perl,
+               libjson-types-perl,
                libmodule-install-perl,
                libmoosex-fileattribute-perl,
                libmoosex-method-signatures-perl,

lib/NGCP/Panel/Controller/API/BillingProfiles.pm

@@ -0,0 +1,183 @@
+package NGCP::Panel::Controller::API::BillingProfiles;
+use Sipwise::Base;
+use namespace::sweep;
+use boolean qw(true);
+use Data::HAL qw();
+use Data::HAL::Link qw();
+use HTTP::Headers qw();
+use HTTP::Status qw(:constants);
+use MooseX::ClassAttribute qw(class_has);
+use NGCP::Panel::Utils::DateTime;
+use NGCP::Panel::Form::BillingProfile::Admin qw();
+use Path::Tiny qw(path);
+BEGIN { extends 'Catalyst::Controller::ActionRole'; }
+require Catalyst::ActionRole::ACL;
+require Catalyst::ActionRole::CheckTrailingSlash;
+require Catalyst::ActionRole::HTTPMethods;
+require Catalyst::ActionRole::RequireSSL;
+
+with 'NGCP::Panel::Role::API';
+with 'NGCP::Panel::Role::API::BillingProfiles';
+
+class_has('resource_name', is => 'ro', default => 'billingprofiles');
+class_has('dispatch_path', is => 'ro', default => '/api/billingprofiles/');
+class_has('relation', is => 'ro', default => 'http://purl.org/sipwise/ngcp-api/#rel-billingprofiles');
+
+__PACKAGE__->config(
+    action => {
+        map { $_ => {
+            ACLDetachTo => '/api/root/invalid_user',
+            AllowedRole => 'api_admin',
+            Args => 0,
+            Does => [qw(ACL CheckTrailingSlash RequireSSL)],
+            Method => $_,
+            Path => __PACKAGE__->dispatch_path,
+        } } @{ __PACKAGE__->allowed_methods }
+    },
+    action_roles => [qw(HTTPMethods)],
+);
+
+sub auto :Private {
+    my ($self, $c) = @_;
+
+    $self->set_body($c);
+    $self->log_request($c);
+}
+
+sub GET :Allow {
+    my ($self, $c) = @_;
+    my $page = $c->request->params->{page} // 1;
+    my $rows = $c->request->params->{rows} // 10;
+    {
+        my $profiles = $c->model('DB')->resultset('billing_profiles');
+        if($c->user->roles eq "api_reseller") {
+            $profiles = $profiles->search({ reseller_id => $c->user->reseller_id });
+        }
+        my $total_count = int($profiles->count);
+        $profiles = $profiles->search(undef, {
+            page => $page,
+            rows => $rows,
+        });
+        my (@embedded, @links);
+        my $form = NGCP::Panel::Form::BillingProfile::Admin->new;
+        for my $profile ($profiles->all) {
+            push @embedded, $self->hal_from_profile($c, $profile, $form);
+            push @links, Data::HAL::Link->new(
+                relation => 'ngcp:'.$self->resource_name,
+                href     => sprintf('/%s%d', $c->request->path, $profile->id),
+            );
+        }
+        push @links,
+            Data::HAL::Link->new(
+                relation => 'curies',
+                href => 'http://purl.org/sipwise/ngcp-api/#rel-{rel}',
+                name => 'ngcp',
+                templated => true,
+            ),
+            Data::HAL::Link->new(relation => 'profile', href => 'http://purl.org/sipwise/ngcp-api/'),
+            Data::HAL::Link->new(relation => 'self', href => sprintf('/%s?page=%s&rows=%s', $c->request->path, $page, $rows));
+
+        if(($total_count / $rows) > $page ) {
+            push @links, Data::HAL::Link->new(relation => 'next', href => sprintf('/%s?page=%d&rows=%d', $c->request->path, $page + 1, $rows));
+        }
+        if($page > 1) {
+            push @links, Data::HAL::Link->new(relation => 'prev', href => sprintf('/%s?page=%d&rows=%d', $c->request->path, $page - 1, $rows));
+        }
+
+        my $hal = Data::HAL->new(
+            embedded => [@embedded],
+            links => [@links],
+        );
+        $hal->resource({
+            total_count => $total_count,
+        });
+        my $rname = $self->resource_name;
+        my $response = HTTP::Response->new(HTTP_OK, undef, HTTP::Headers->new(
+            (map { # XXX Data::HAL must be able to generate links with multiple relations
+                s|rel="(http://purl.org/sipwise/ngcp-api/#rel-$rname)"|rel="item $1"|;
+                s/rel=self/rel="collection self"/;
+                $_
+            } $hal->http_headers),
+        ), $hal->as_json);
+        $c->response->headers($response->headers);
+        $c->response->body($response->content);
+        return;
+    }
+    return;
+}
+
+sub HEAD :Allow {
+    my ($self, $c) = @_;
+    $c->forward(qw(GET));
+    $c->response->body(q());
+    return;
+}
+
+sub OPTIONS :Allow {
+    my ($self, $c) = @_;
+    my $allowed_methods = $self->allowed_methods;
+    $c->response->headers(HTTP::Headers->new(
+        Allow => $allowed_methods->join(', '),
+        Accept_Post => 'application/hal+json; profile=http://purl.org/sipwise/ngcp-api/#rel-'.$self->resource_name,
+    ));
+    $c->response->content_type('application/json');
+    $c->response->body(JSON::to_json({ methods => $allowed_methods })."\n");
+    return;
+}
+
+sub POST :Allow {
+    my ($self, $c) = @_;
+
+    my $guard = $c->model('DB')->txn_scope_guard;
+    {
+        my $schema = $c->model('DB');
+        my $resource = $self->get_valid_post_data(
+            c => $c, 
+            media_type => 'application/json',
+        );
+        last unless $resource;
+
+        if($c->user->roles eq "api_admin") {
+        } elsif($c->user->roles eq "api_reseller") {
+            $resource->{reseller_id} = $c->user->reseller_id;
+        } else {
+            $resource->{reseller_id} = $c->user->contract->contact->reseller_id;
+        }
+
+        my $form = NGCP::Panel::Form::BillingProfile::Admin->new;
+        last unless $self->validate_form(
+            c => $c,
+            resource => $resource,
+            form => $form,
+        );
+
+        my $reseller = $schema->resultset('resellers')->find($resource->{reseller_id});
+        unless($reseller) {
+            $self->error($c, HTTP_UNPROCESSABLE_ENTITY, "Invalid 'reseller_id'.");
+            last;
+        }
+        my $billing_profile;
+        try {
+            $billing_profile= $schema->resultset('billing_profiles')->create($resource);
+        } catch($e) {
+            $c->log->error("failed to create billing profile: $e"); # TODO: user, message, trace, ...
+            $self->error($c, HTTP_INTERNAL_SERVER_ERROR, "Failed to create billing profile.");
+            last;
+        }
+
+        $guard->commit;
+
+        $c->response->status(HTTP_CREATED);
+        $c->response->header(Location => sprintf('%s%d', $self->dispatch_path, $billing_profile->id));
+        $c->response->body(q());
+    }
+    return;
+}
+
+sub end : Private {
+    my ($self, $c) = @_;
+
+    $self->log_response($c);
+}
+
+# vim: set tabstop=4 expandtab:

lib/NGCP/Panel/Role/API.pm

@@ -4,6 +4,7 @@ use Sipwise::Base;
 
 use JSON qw();
 use JSON::Pointer;
+use JSON::Types qw(bool);
 use HTTP::Status qw(:constants);
 use Safe::Isa qw($_isa);
 use Try::Tiny;
@@ -96,8 +97,13 @@ sub validate_form {
         $resource->{$k} = DateTime::Format::RFC3339->format_datetime($resource->{$k})
             if $resource->{$k}->$_isa('DateTime');
         $resource->{$k} = $resource->{$k} + 0
-            if($form->field($k)->$_isa('HTML::FormHandler::Field::Integer') ||
+            if(defined $resource->{$k} && (
-               $form->field($k)->$_isa('HTML::FormHandler::Field::Float'));
+               $form->field($k)->$_isa('HTML::FormHandler::Field::Integer') ||
+               $form->field($k)->$_isa('HTML::FormHandler::Field::Money') ||
+               $form->field($k)->$_isa('HTML::FormHandler::Field::Float')));
+        $resource->{$k} = JSON::Types::bool($resource->{$k})
+            if(defined $resource->{$k} && 
+               $form->field($k)->$_isa('HTML::FormHandler::Field::Boolean'));
     }
 
     if($run) {

lib/NGCP/Panel/Role/API/BillingProfiles.pm

@@ -0,0 +1,129 @@
+package NGCP::Panel::Role::API::BillingProfiles;
+use Moose::Role;
+use Sipwise::Base;
+
+use boolean qw(true);
+use Try::Tiny;
+use Data::HAL qw();
+use Data::HAL::Link qw();
+use HTTP::Status qw(:constants);
+use NGCP::Panel::Utils::DateTime;
+use NGCP::Panel::Utils::Contract;
+use NGCP::Panel::Form::BillingProfile::Admin qw();
+
+sub hal_from_profile {
+    my ($self, $c, $profile, $form) = @_;
+
+    my %resource = $profile->get_inflated_columns;
+
+    my $hal = Data::HAL->new(
+        links => [
+            Data::HAL::Link->new(
+                relation => 'curies',
+                href => 'http://purl.org/sipwise/ngcp-api/#rel-{rel}',
+                name => 'ngcp',
+                templated => true,
+            ),
+            Data::HAL::Link->new(relation => 'collection', href => sprintf('/api/%s/', $self->resource_name)),
+            Data::HAL::Link->new(relation => 'profile', href => 'http://purl.org/sipwise/ngcp-api/'),
+            # TODO: if called from collection, this is wrong, as the id is missing when we put it into embedded! Same for systemcontacts/contracts:
+            Data::HAL::Link->new(relation => 'self', href => sprintf("%s%d", $self->dispatch_path, $profile->id)),
+            map { Data::HAL::Link->new(relation => 'ngcp:billingfees', href => sprintf("/api/billingfees/%d", $_->id)) } $profile->billing_fees->all,
+        ],
+        relation => 'ngcp:'.$self->resource_name,
+    );
+
+    $form //= NGCP::Panel::Form::BillingProfile::Admin->new;
+    return unless $self->validate_form(
+        c => $c,
+        form => $form,
+        resource => \%resource,
+        run => 0,
+    );
+
+    $resource{id} = int($profile->id);
+    $hal->resource({%resource});
+    return $hal;
+}
+
+sub contract_by_id {
+    my ($self, $c, $id) = @_;
+
+    # we only return system contracts, that is, those with contacts without
+    # reseller
+    my $contracts = NGCP::Panel::Utils::Contract::get_contract_rs(
+        schema => $c->model('DB'),
+    );
+    $contracts = $contracts->search({
+        'contact.reseller_id' => undef
+    },{
+        join => 'contact',
+        '+select' => 'billing_mappings.id',
+        '+as' => 'bmid',
+    });
+
+    return $contracts->find($id);
+}
+
+sub update_contract {
+    my ($self, $c, $contract, $old_resource, $resource, $form) = @_;
+
+    my $billing_mapping = $contract->billing_mappings->find($contract->get_column('bmid'));
+    $old_resource->{billing_profile_id} = $billing_mapping->billing_profile_id; 
+    $resource->{billing_profile_id} //= $old_resource->{billing_profile_id};
+   
+    $form //= NGCP::Panel::Form::Contract::PeeringReseller->new;
+    return unless $self->validate_form(
+        c => $c,
+        form => $form,
+        resource => $resource,
+    );
+
+    my $now = NGCP::Panel::Utils::DateTime::current_local;
+    $resource->{modify_timestamp} = $now;
+
+    if($old_resource->{billing_profile_id} != $resource->{billing_profile_id}) {
+        my $billing_profile = $c->model('DB')->resultset('billing_profiles')->find($resource->{billing_profile_id});
+        unless($billing_profile) {
+            $self->error($c, HTTP_UNPROCESSABLE_ENTITY, "Invalid 'billing_profile_id'");
+            return;
+        }
+        $contract->billing_mappings->create({
+            start_date => NGCP::Panel::Utils::DateTime::current_local,
+            billing_profile_id => $resource->{billing_profile_id},
+            product_id => $billing_mapping->product_id,
+        });
+    }
+    delete $resource->{billing_profile_id};
+
+
+    if($old_resource->{contact_id} != $resource->{contact_id}) {
+        my $syscontact = $c->model('DB')->resultset('contacts')
+            ->search({ reseller_id => undef })
+            ->find($resource->{contact_id});
+        unless($syscontact) {
+            $self->error($c, HTTP_UNPROCESSABLE_ENTITY, "Invalid 'contact_id'");
+            return;
+        }
+    }
+
+    $contract->update($resource);
+
+    if($old_resource->{status} ne $resource->{status}) {
+        if($contract->id == 1) {
+            $self->error($c, HTTP_FORBIDDEN, "Cannot set contract status to '".$resource->{status}."' for contract id '1'");
+            return;
+        }
+        NGCP::Panel::Utils::Contract::recursively_lock_contract(
+            c => $c,
+            contract => $contract,
+        );
+    }
+
+    # TODO: what about changed product, do we allow it?
+
+    return $contract;
+}
+
+1;
+# vim: set tabstop=4 expandtab:

lib/NGCP/Panel/Role/API/Contracts.pm

@@ -52,7 +52,7 @@ sub hal_from_contract {
             ),
             Data::HAL::Link->new(relation => 'collection', href => sprintf('/api/%s/', $self->resource_name)),
             Data::HAL::Link->new(relation => 'profile', href => 'http://purl.org/sipwise/ngcp-api/'),
-            Data::HAL::Link->new(relation => 'self', href => sprintf("/%s", $c->request->path)),
+            Data::HAL::Link->new(relation => 'self', href => sprintf("%s%d", $self->dispatch_path, $contract->id)),
             Data::HAL::Link->new(relation => 'ngcp:systemcontacts', href => sprintf("/api/systemcontacts/%d", $contract->contact->id)),
             Data::HAL::Link->new(relation => 'ngcp:billingprofiles', href => sprintf("/api/billingprofiles/%d", $billing_profile_id)),
             Data::HAL::Link->new(relation => 'ngcp:contractbalances', href => sprintf("/api/contractbalances/%d", $contract_balance->id)),

lib/NGCP/Panel/Role/API/SystemContacts.pm

@@ -23,7 +23,7 @@ sub hal_from_contact {
             ),
             Data::HAL::Link->new(relation => 'collection', href => sprintf("/api/%s/", $self->resource_name)),
             Data::HAL::Link->new(relation => 'profile', href => 'http://purl.org/sipwise/ngcp-api/'),
-            Data::HAL::Link->new(relation => 'self', href => sprintf("/%s", $c->request->path)),
+            Data::HAL::Link->new(relation => 'self', href => sprintf("%s%d", $self->dispatch_path, $contact->id)),
         ],
         relation => 'ngcp:'.$self->resource_name,
     );